Move common build logic to convention plugins

build-logic/build.gradle.kts

@@ -0,0 +1,28 @@
+plugins {
+    `kotlin-dsl`
+}
+
+repositories {
+    maven {
+        name = "Architectury"
+        url = uri("https://maven.architectury.dev")
+    }
+    maven {
+        name = "Fabric"
+        url = uri("https://maven.fabricmc.net")
+    }
+    maven {
+        name = "NeoForge"
+        url = uri("https://maven.neoforged.net/releases")
+    }
+    gradlePluginPortal()
+}
+
+dependencies {
+    implementation(libs.architectury.loom)
+    implementation(libs.architectury.plugin)
+
+    // Enable using version catalog in local plugins
+    // https://github.com/gradle/gradle/issues/15383
+    implementation(files(libs.javaClass.superclass.protectionDomain.codeSource.location))
+}

build-logic/settings.gradle.kts

@@ -0,0 +1,13 @@
+pluginManagement {
+    repositories {
+        gradlePluginPortal()
+    }
+}
+
+dependencyResolutionManagement {
+    versionCatalogs {
+        create("libs") {
+            from(files("../gradle/libs.versions.toml"))
+        }
+    }
+}

build-logic/src/main/kotlin/dynamic_fps.base.gradle.kts

@@ -0,0 +1,30 @@
+plugins {
+    id("base")
+}
+
+val baseName = project.property("archives_name").toString()
+
+val mavenGroup = project.property("maven_group").toString()
+val modVersion = project.property("mod_version").toString()
+
+base {
+    archivesName = baseName
+}
+
+group = mavenGroup
+version = modVersion
+
+if (project.hasProperty("loom.platform")) {
+    val platform = project.property("loom.platform")
+    val minecraft = project.property("minecraft_version_min")
+
+    version = "${modVersion}+minecraft-${minecraft}-${platform}"
+}
+
+tasks.withType<ProcessResources> {
+    inputs.property("version", modVersion)
+
+    filesMatching(listOf("fabric.mod.json", "mods.toml", "neoforge.mods.toml", "quilt.mod.json")) {
+        expand(inputs.properties)
+    }
+}

build-logic/src/main/kotlin/dynamic_fps.java.gradle.kts

@@ -0,0 +1,19 @@
+plugins {
+    id("java")
+}
+
+java {
+    withSourcesJar()
+
+    toolchain {
+        languageVersion = JavaLanguageVersion.of(21)
+    }
+}
+
+tasks.withType<JavaCompile> {
+    options.encoding = "UTF-8"
+
+    javaCompiler = javaToolchains.compilerFor {
+        languageVersion = JavaLanguageVersion.of(21)
+    }
+}

build-logic/src/main/kotlin/dynamic_fps.module.gradle.kts

@@ -0,0 +1,36 @@
+import org.gradle.accessors.dm.LibrariesForLibs
+
+plugins {
+    id("dynamic_fps.base")
+    id("dynamic_fps.java")
+    id("architectury-plugin")
+    id("dev.architectury.loom")
+}
+
+val libs = the<LibrariesForLibs>()
+
+architectury {
+    minecraft = libs.versions.minecraft.get()
+}
+
+loom {
+    silentMojangMappingsLicense()
+
+    mods.create("dynamic_fps") {
+        sourceSet(sourceSets.main.get())
+    }
+}
+
+repositories {
+    maven {
+        name = "LostLuma"
+        url = uri("https://maven.lostluma.net/releases")
+    }
+}
+
+dependencies {
+    minecraft(libs.minecraft)
+    mappings(loom.officialMojangMappings())
+
+    implementation(libs.battery)
+}

build.gradle.kts

@@ -0,0 +1,3 @@
+plugins {
+    alias(libs.plugins.architectury.loom).apply(false)
+}

gradle.properties

@@ -7,7 +7,7 @@ org.gradle.jvmargs = -Xmx3G
 mod_version = 3.6.0
 
 maven_group = juliand665
-archives_base_name = dynamic-fps
+archives_name = dynamic-fps
 
 # Game Properties
 minecraft_version_min = 1.21.0

gradle/libs.versions.toml

@@ -24,6 +24,9 @@ cloth_config = "15.0.127"
 
 mixinextras = "0.3.5"
 
+architectury = "3.4.155"
+architectury_loom = "1.6.397"
+
 [libraries]
 minecraft = { module = "com.mojang:minecraft", version.ref = "minecraft" }
 
@@ -51,10 +54,9 @@ cloth_config = { module = "me.shedaniel.cloth:cloth-config", version.ref = "clot
 mixinextras_common = { module = "io.github.llamalad7:mixinextras-common", version.ref = "mixinextras" }
 mixinextras_forge = { module = "io.github.llamalad7:mixinextras-forge", version.ref = "mixinextras" }
 
-[bundles]
+architectury_plugin = { module = "architectury-plugin:architectury-plugin.gradle.plugin", version.ref = "architectury" }
+architectury_loom = { module = "dev.architectury.loom:dev.architectury.loom.gradle.plugin", version.ref = "architectury_loom" }
 
 [plugins]
 shadow = { id = "com.github.johnrengelman.shadow", version = "8.1.1" }
-
-architectury = { id = "architectury-plugin", version = "3.4.155" }
-architectury_loom = { id = "dev.architectury.loom", version = "1.6.397" }
+architectury_loom = { id = "dev.architectury.loom", version.ref = "architectury_loom" }

platforms/common/build.gradle.kts

@@ -0,0 +1,19 @@
+plugins {
+	id("dynamic_fps.module")
+}
+
+val platforms = project.property("enabled_platforms").toString()
+
+architectury {
+	common(platforms.split(","))
+}
+
+loom {
+	accessWidenerPath = file("src/main/resources/dynamic_fps.accesswidener")
+}
+
+dependencies {
+    modImplementation(libs.cloth.config)
+    // Note: This is only here for the @Environment annotation, do not use!
+	modImplementation(libs.fabric.loader)
+}

platforms/fabric/build.gradle

@@ -1,4 +1,5 @@
 plugins {
+	id("dynamic_fps.module")
 	alias libs.plugins.shadow
 }
 
@@ -41,14 +42,6 @@ dependencies {
 	shadowCommon(project(path: ":platforms:common", configuration: "transformProductionFabric")) { transitive false }
 }
 
-processResources {
-	inputs.property "version", rootProject.mod_version
-
-	filesMatching("fabric.mod.json") {
-		expand "version": rootProject.mod_version
-	}
-}
-
 shadowJar {
 	exclude "architectury.common.json"
 	configurations = [project.configurations.shadowCommon]
@@ -71,17 +64,3 @@ components.java {
 		skip()
 	}
 }
-
-publishing {
-	publications {
-		mavenFabric(MavenPublication) {
-			artifactId = rootProject.archives_base_name + "-" + project.name
-			from components.java
-		}
-	}
-
-	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
-	repositories {
-		// Add repositories to publish to here.
-	}
-}

platforms/forge/build.gradle

@@ -1,4 +1,5 @@
 plugins {
+	id("dynamic_fps.module")
 	alias libs.plugins.shadow
 }
 
@@ -40,14 +41,6 @@ dependencies {
 	shadowCommon(project(path: ":platforms:common", configuration: "transformProductionForge")) { transitive = false }
 }
 
-processResources {
-	inputs.property "version", rootProject.mod_version
-
-	filesMatching("META-INF/mods.toml") {
-		expand "version": rootProject.mod_version
-	}
-}
-
 shadowJar {
 	exclude "fabric.mod.json"
 	exclude "architectury.common.json"
@@ -71,17 +64,3 @@ components.java {
 		skip()
 	}
 }
-
-publishing {
-	publications {
-		mavenForge(MavenPublication) {
-			artifactId = rootProject.archives_base_name + "-" + project.name
-			from components.java
-		}
-	}
-
-	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
-	repositories {
-		// Add repositories to publish to here.
-	}
-}