build.gradle

plugins {
    id "architectury-plugin" version "3.4-SNAPSHOT"
    id "dev.architectury.loom" version "1.5-SNAPSHOT" apply false
}

architectury {
    minecraft = rootProject.minecraft_version
}

subprojects {
    apply plugin: "dev.architectury.loom"

    loom {
        silentMojangMappingsLicense()
    }

    dependencies {
        minecraft "com.mojang:minecraft:${rootProject.minecraft_version}"
        mappings (loom.layered {
            it.mappings "net.fabricmc:yarn:${rootProject.minecraft_version}+build.${rootProject.yarn_build}:v2"

            it.mappings rootProject.file("mappings/yarn-custom.tiny")
        })
    }
}

allprojects {
    apply plugin: "java"
    apply plugin: "architectury-plugin"
    apply plugin: "maven-publish"

    archivesBaseName = "${rootProject.mod_id}-${project.name}+${rootProject.minecraft_version}"
    version = rootProject.mod_version
    group = rootProject.maven_group

    repositories {
        maven {
            name = 'Tterrag Maven'
            url = 'https://maven.tterrag.com/'
        }
        maven {
            name = "Devos Maven"
            url = "https://mvn.devos.one/snapshots/"
        }
    }

    tasks.withType(JavaCompile) {
        options.encoding = "UTF-8"
        options.release.set(17)
    }

    java {
        withSourcesJar()
    }
}