How to match this kind of color text?

[hairui]

While scripting bots in PKUXKX, I met with a color text to trigger,which looked like:
\e[44;1m\e[1;37m尚\e[44;1m\e[1;37m春\e[44;1m\e[1;37m伤\e[44;1m\e[1;37m弟\e[44;1m\e[1;37m肉\e[44;1m\e[1;37m道\e[42;1m\e[1;37m论\e[42;1m\e[1;37m灯\e[46;1m\e[1;37m竹\e[42;1m\e[1;37m逍\e[43;1m\e[1;37m营\e[2;37;0m

I wrote a script to match the text. like :
`
#class {CT} {kill};
#class {CT} {open};

#alias kys {#config {convert meta} on}
#alias bkys {#config {convert meta} off}

#debug act on;

#act {~\e[{\d{2}};1m\e[1;37m{\W+}} {
#showme %1 %2;
#echo %0;
};

#class {CT} {close};
`

It's result:

`
#DEBUG ACTION {~\e[{\d{2}};1m\e[1;37m{\W+}}

#showme 44 尚

44 尚

#echo 尚

尚
`

The action just matched the first appearance of the color Chinese character. But what I need is to get each character and its backgroud color.
So what should I do? Any help would be much appreciated

[hairui]

I know i can write a script such as :
#act {~\e[%d;1m\e[1;37m%+\e[44;1m\e[1;37m%+\e[44;1m\e[1;37m%+\e[44;1m\e[1;37m%+\e[44;1m\e[1;37m%+\e[44;1m\e[1;37m%+\e[42;1m\e[1;37m%+\e[42;1m\e[1;37m%+\e[46;1m\e[1;37m%+\e[42;1m\e[1;37m%+\e[43;1m\e[1;37m%+\e[2;37;0m} {}
to match the color text.
But the problem is the length of the text is always changing.

[scandum]

This seems to work for me:

#line sub esc #var test {\e[44;1m\e[1;37m尚\e[44;1m\e[1;37m春\e[44;1m\e[1;37m伤\e[44;1m\e[1;37m弟\e[44;1m\e[1;37m肉\e[44;1m\e[1;37m道\e[42;1m\e[1;37m论\e[42;1m\e[1;37m灯}

#replace test {{[^\e[0-9;m]+}} {&1__}

#list test explode {__}

#showme $test[1], $test[-1]

#list explode requires the latest version to work properly.

[hairui]

Thanks, @scandum
I have modified my script into:
`

    #act {~%+\e[2;37;0m$} {
            #line sub esc #var test %1;
            #replace test {{[^\e[0-9;m]+}} {&1__};
            #list test explode {__};
            #foreach {$test} {bn} {#echo $bn};
    };

`

Alought i am not sure what is #line sub esc used for.
It seems there is not much description for this black magic in the manual.
Btw. why can I still see the color while echoing each character?

[scandum]

Using #line sub esc might not be secure, I was using it just for testing, and more reliable to use #echo %s:

#act {~%+\e[2;37;0m$} {
            #var test {%1};
            #replace test {{[^\e[0-9;m]+}} {&1__};
            #list test explode {__};
            #foreach {$test} {bn} {#echo %s {$bn}};
    };

[scandum]

As for what it does, #line sub esc is short for substitute escapes and turns \e into the actual code.

If you want to remove color codes you can try:

#replace test {{[^\e[0-9;m]+}} {&1__};
#line sub var #line strip #var test {$test};

[scandum]

If you don't want to see color the following should work as well:

#act {~%+\e[2;37;0m$} {
            #line strip #var test {%1};
            #parse {$test} {bn} {#echo %s {$bn}};
    };