Looping through a list of strings to set actions

[HeyParkerJ]

Alternate title: Can you reference variables when setting an action?

So I'm not sure if I'm totally off my rocker when it comes to how I've tried to structure this code and its data, but I'm attempting to create a list of statuses, their "buff applied" message (called "don") and "buff unapplied" messages (referred to as "doff"), and then loop through the table in order to create actions that will update each buff's status as the don and doff messages are read.

It appears that, when declaring a trigger, variables are escaped and taken into the action as a literal string. If I try to create a trigger with the variable from nested table $buffs[%1][don]} - the trigger is searching for the message $buffs[%1][don]} literally. In other words, it seems impossible to programmatically declare triggers with their messages sourced from a list of strings. I understand that I could format this a lot more flat with each string creating its own trigger, but this is to be the basis for a rather large set of scripts I was hoping to create and being able to do something like this would be incredibly useful in terms of maintenance.

#class {rebuff} {open}

#VARIABLE {buffs} {
  {FocusMind} {
    {status} {off}
    {don} {You stop focusing your mind.}
    {doff} {You focus your mind for battle.}
    {statusMsg} {Your mind is focused.}
  }
  {Strength} {
    {status} {off}
    {don} {You feel weaker.}
    {doff} {You feel the Force flow through you and make you stronger!}
    {statusMsg} {You feel the force rippling through your muscles.}
  }
  {ForceSpeed} {
    {status} {off}
    {don} {You feel much slower.}
    {doff} {You feel quicker.}
    {statusMsg} {Your speed is enhanced.}
  }
  {ForceReflex} {
    {status} {off}
    {don} {Your focus on your fighting abilities begins to fade.}
    {doff} {You focus yourself and ready yourself for battle.}
    {scoreStatus} {Your reflexes and instincts have been heightened by the force.}
  }
 #nop etc for about 30 buffs
}

/*
This is the source of my pain
*/
#loop {1} {&buffs[]} {x} #action {$buffs[%1][don]}} {
  #replace $buffs[+$x][status] {on}
}

#loop {1} {&buffs[]} {x} #action {$buffs[%1][statusMsg]}} {
  #replace $buffs[+$x][status] {on}
}

#loop {1} {&buffs[]} {x} #action {$buffs[%1][doff]}} {
  #replace $buffs[+$x][status] {off}
}

#alias {printBuffs} {
  #loop {1} {&buffs[]} {i} {#show *buffs[+$i] $buffs[+$i][status]}
}
#class {rebuff} {close}

Thank you for your work maintaining TT++ btw. I love this software :D

[scandum]

Don't think you're using #replace properly. Try the following:

#loop {1} {&buffs[]} {x} #line substitute variables #action {$buffs[%1][don]}} {
  #replace $buffs[+$x][status] {on}
}

Assuming you want to set the variable to on, try:

#loop {1} {&buffs[]} {x} #line substitute variables #action {$buffs[+$x][don]} {
  #var buffs[+$x][status] {on}
}

Keep in mind you can't alter the buffs variable table after those actions are set, or the indexing will be incorrect.

[HeyParkerJ]

Thank you that worked perfectly. Final code below in case anyone finds it useful

#class {rebuff} {open}

/*
   Updating this var in game won't change the action,
   because the alias is already set,
   but you can hardcode this variable to turn it off for good
*/
#VARIABLE {reapply} {on}

/*
don: message when buff is successfully applied
doff: message when buff is un-applied
scoreStatus: If your message supports it, the message that your MUD sends when you check your applied buffs (ex: score)
reapply: command to reapply buff
*/
#VARIABLE {buffs} {
  {Hunger} {
    {status} {on}
    {don} {You are no longer hungry.}
    {doff} {You feel a rumble in your gut.}
    {scoreStatus} {You are hungry.}
    {reapply} {drink flask}
  }
  {Thirst} {
    {status} {on}
    {don} {You don't feel thirsty anymore.}
    {doff} {Your throat is getting dry.}
    {scoreStatus} {You are thirsty.}
    {reapply} {drink flask}
  }
  {FocusMind} {
    {status} {off}
    {don} {You focus your mind for battle.}
    {doff} {You stop focusing your mind.}
    {scoreStatus} {Your mind is focused.}
    {reapply} {conc 'focus mind'}
  }
  {Strength} {
    {status} {off}
    {don} {You feel the Force flow through you and make you stronger!}
    {doff} {You feel weaker.}
    {scoreStatus} {You feel the force rippling through your muscles.}
    {reapply} {conc 'stren'}
  }
}

/* Print Buffs */
#alias {pb} {
  #loop {1} {&buffs[]} {a} {
    #if {"$buffs[+$a][status]" == "on"} {
      #show $green*buffs[+$a] $buffs[+$a][status]
    };
    #if {"$buffs[+$a][status]" == "off"} {
      #show $red*buffs[+$a] $buffs[+$a][status]
    };
  }
}

/* Missing Buffs */
#alias {mb} {
  #loop {1} {&buffs[]} {b} {
    #if {"$buffs[+$b][status]" == "off"} {
      #show $red*buffs[+$b] $buffs[+$b][status]
    }
  }
}

/* Apply missing buffs */
#alias {rebuff} {
  #loop {1} {&buffs[]} {c} {
    #if {"$buffs[+$c][status]" == "off"} {
      $buffs[+$c][reapply]
    }
  }
  #var {c} {1}
}

#if {#line substitute variables $buffs[+$b][status] == 'off'} {#show yeah}

/* When we read the don string, set status to 'on' */
#loop {1} {&buffs[]} {x} #line substitute variables #action {$buffs[+$x][don]} {
  #var buffs[+$x][status] {on}
}

/* When we read the doff string, set status to 'off' */
#loop {1} {&buffs[]} {z} #line substitute variables #action {$buffs[+$z][doff]} {
  #var buffs[+$z][status] {off};
  #if {"$reapply" == "on"} {$buffs[+$z][reapply]};
}

/* Assuming your MUD has a method to list your applied buffs, this will take those strings and set their status to 'on' */
#loop {1} {&buffs[]} {y} #line substitute variables #action {$buffs[+$y][scoreStatus]} {
  #var buffs[+$y][status] {on}
}

#class {rebuff} {close}