-
Notifications
You must be signed in to change notification settings - Fork 2
/
Copy pathDC3D.f90
1433 lines (1373 loc) · 47.2 KB
/
DC3D.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
!----------------------------------------------------------------------
subroutine DC3D0(ALPHA,X,Y,Z,DEPTH,DIP,POT1,POT2,POT3,POT4, &
UX,UY,UZ,UXX,UYX,UZX,UXY,UYY,UZY,UXZ,UYZ,UZZ,IRET)
!********************************************************************
!***** *****
!***** DISPLACEMENT AND STRAIN AT DEPTH *****
!***** DUE TO BURIED POINT SOURCE IN A SEMIINFINITE MEDIUM *****
!***** CODED BY Y.OKADA ... SEP.1991 *****
!***** REVISED NOV.1991, MAY.2002 *****
!--------------------------------------------------------------------
!----- converted to Fortran90 (free form) -----
!----- T. Miyashita, Jan. 2020 -----
!--------------------------------------------------------------------
!***** *****
!********************************************************************
!
!***** INPUT
!***** ALPHA : MEDIUM CONSTANT (LAMBDA+MYU)/(LAMBDA+2*MYU)
!***** X,Y,Z : COORDINATE OF OBSERVING POINT
!***** DEPTH : SOURCE DEPTH
!***** DIP : DIP-ANGLE (DEGREE)
!***** POT1-POT4 : STRIKE-, DIP-, TENSILE- AND INFLATE-POTENCY
!***** POTENCY=( MOMENT OF DOUBLE-COUPLE )/MYU FOR POT1,2
!***** POTENCY=(INTENSITY OF ISOTROPIC PART)/LAMBDA FOR POT3
!***** POTENCY=(INTENSITY OF LINEAR DIPOLE )/MYU FOR POT4
!
!***** OUTPUT
!***** UX, UY, UZ : DISPLACEMENT ( UNIT=(UNIT OF POTENCY) /
!***** : (UNIT OF X,Y,Z,DEPTH)**2 )
!***** UXX,UYX,UZX : X-DERIVATIVE ( UNIT= UNIT OF POTENCY) /
!***** UXY,UYY,UZY : Y-DERIVATIVE (UNIT OF X,Y,Z,DEPTH)**3 )
!***** UXZ,UYZ,UZZ : Z-DERIVATIVE
!***** IRET : return CODE
!***** : =0....NORMAL
!***** : =1....SINGULAR
!***** : =2....POSITIVE Z WAS GIVEN
implicit none
! arguments
real*8, intent(in) :: ALPHA,X,Y,Z,DEPTH,DIP,POT1,POT2,POT3,POT4
real*8, intent(out) :: UX,UY,UZ,UXX,UYX,UZX,UXY,UYY,UZY,UXZ,UYZ,UZZ
integer, intent(out) :: IRET
! local variables
real*8 :: ALP(5)
real*8 :: U(12),DUA(12),DUB(12),DUC(12)
real*8 :: DU
real*8 :: SD,CD,R
real*8 :: XX,YY,ZZ,DD
! parameters
real*8, parameter :: EPS=1.0d-6
! loop counter
integer :: I
! initialization
U(1:12) = 0.0d0
DUA(1:12) = 0.0d0
DUB(1:12) = 0.0d0
DUC(1:12) = 0.0d0
call varout(U,UX,UY,UZ,UXX,UYX,UZX,UXY,UYY,UZY,UXZ,UYZ,UZZ)
!### CAUTION ### if X,Y,D ARE SUFFICIENTLY SMALL, THEY ARE SET TO ZERO
XX=X
YY=Y
ZZ=Z
DD=DEPTH+Z
if(dabs(XX)<EPS) XX=0.0d0
if(dabs(YY)<EPS) YY=0.0d0
if(dabs(DD)<EPS) DD=0.0d0
!-----
IRET=0
if(Z>0.0d0) then
IRET=2
return
endif
!-----
R=dsqrt(XX*XX+YY*YY+DD*DD)
if (R==0.0d0) then !IN CASE OF SINGULAR (R=0)
IRET=1
return
endif
!**********************************************************************
!***** CALCULATE STATION GEOMETRY CONSTANTS FOR POINT SOURCE *****
!**********************************************************************
call assign_alpha(ALPHA,ALP)
call DCCON0(DIP,SD,CD)
!======================================
!===== REAL-SOURCE CONTRIBUTION =====
!======================================
!-----
call UA0(XX,YY,DD,POT1,POT2,POT3,POT4,SD,CD,ALP,DUA)
!-----
do 222 I=1,12
if(I<10) U(I)=U(I)-DUA(I)
if(I>=10) U(I)=U(I)+DUA(I)
222 enddo
!=======================================
!===== IMAGE-SOURCE CONTRIBUTION =====
!=======================================
DD=DEPTH-Z
call UA0(XX,YY,DD,POT1,POT2,POT3,POT4,SD,CD,ALP,DUA)
call UB0(XX,YY,DD,ZZ,POT1,POT2,POT3,POT4,SD,CD,ALP,DUB)
call UC0(XX,YY,DD,ZZ,POT1,POT2,POT3,POT4,SD,CD,ALP,DUC)
!-----
do 333 I=1,12
DU=DUA(I)+DUB(I)+ZZ*DUC(I)
if(I>=10) DU=DU+DUC(I-9)
U(I)=U(I)+DU
333 enddo
!=====
call varout(U,UX,UY,UZ,UXX,UYX,UZX,UXY,UYY,UZY,UXZ,UYZ,UZZ)
return
end subroutine DC3D0
!----------------------------------------------------------------------
!----------------------------------------------------------------------
subroutine UA0(X,Y,D,POT1,POT2,POT3,POT4,SD,CD,ALP,U)
!********************************************************************
!***** DISPLACEMENT AND STRAIN AT DEPTH (PART-A) *****
!***** DUE TO BURIED POINT SOURCE IN A SEMIINFINITE MEDIUM *****
!********************************************************************
!
!***** INPUT
!***** X,Y,D : STATION COORDINATES IN FAULT SYSTEM
!***** POT1-POT4 : STRIKE-, DIP-, TENSILE- AND INFLATE-POTENCY
!***** OUTPUT
!***** U(12) : DISPLACEMENT AND THEIR DERIVATIVES
implicit none
! arguments
real*8, intent(in) :: X,Y,D
real*8, intent(in) :: POT1,POT2,POT3,POT4
real*8, intent(in) :: SD,CD
real*8, intent(in) :: ALP(5)
real*8, intent(out) :: U(12)
! local variables
real*8 :: DU(12)
real*8 :: P,Q,S,T
real*8 :: R, R2, R3, R5
real*8 :: S2D,C2D
real*8 :: QR,QRX
real*8 :: XY,X2,Y2,D2,A3,A5,B3,C3
real*8 :: UY,VY,WY,UZ,VZ,WZ
! parameters
real*8, parameter :: PI2=6.283185307179586D0
real*8, parameter :: F0=0.0d0, F1=1.0d0, F3=3.0d0, F5=5.0d0
! loop counter
integer :: I
U(1:12)=0.0d0
DU(1:12)=0.0d0
call DCCON1(X,Y,D,SD,CD,R,P,Q,S,T)
S2D=2.0d0*SD*CD
C2D=CD*CD-SD*SD
XY=X*Y
X2=X*X
Y2=Y*Y
D2=D*D
R2=R**2.0d0
R3=R**3.0d0
R5=R**5.0d0
QR=F3*Q/R5 ! 3q/(R^5)
QRX=F5*QR*X/R2 ! 15qx/(R^7)
! -- Eq.(8), p.1024 --
A3=F1-F3*X2/R2
A5=F1-F5*X2/R2
B3=F1-F3*Y2/R2
C3=F1-F3*D2/R2
!-----
! -- Tab.4 and 5, pp.1027-1028 --
UY=SD-F5*Y*Q/R2 ! U in Tab.4
UZ=CD+F5*D*Q/R2 ! U' in Tab.5
VY=S -F5*Y*P*Q/R2 ! V in Tab.4
VZ=T +F5*D*P*Q/R2 ! V' in Tab.5
WY=UY+SD ! W in Tab.4
WZ=UZ+CD ! W' in Tab.5
!-----
!======================================
!===== STRIKE-SLIP CONTRIBUTION =====
!======================================
if(POT1/=F0) then
DU( 1)= ALP(1)*Q/R3 +ALP(2)*X2*QR
DU( 2)= ALP(1)*X/R3*SD +ALP(2)*XY*QR
DU( 3)=-ALP(1)*X/R3*CD +ALP(2)*X*D*QR
DU( 4)= X*QR*(-ALP(1) +ALP(2)*(F1+A5) )
DU( 5)= ALP(1)*A3/R3*SD +ALP(2)*Y*QR*A5
DU( 6)=-ALP(1)*A3/R3*CD +ALP(2)*D*QR*A5
DU( 7)= ALP(1)*(SD/R3-Y*QR) +ALP(2)*F3*X2/R5*UY
DU( 8)= F3*X/R5*(-ALP(1)*Y*SD +ALP(2)*(Y*UY+Q) )
DU( 9)= F3*X/R5*( ALP(1)*Y*CD +ALP(2)*D*UY )
DU(10)= ALP(1)*(CD/R3+D*QR) +ALP(2)*F3*X2/R5*UZ
DU(11)= F3*X/R5*( ALP(1)*D*SD +ALP(2)*Y*UZ )
DU(12)= F3*X/R5*(-ALP(1)*D*CD +ALP(2)*(D*UZ-Q) )
do 222 I=1,12
U(I)=U(I)+POT1/PI2*DU(I)
222 enddo
endif
!===================================
!===== DIP-SLIP CONTRIBUTION =====
!===================================
if(POT2/=F0) then
DU( 1)= ALP(2)*X*P*QR
DU( 2)= ALP(1)*S/R3 +ALP(2)*Y*P*QR
DU( 3)=-ALP(1)*T/R3 +ALP(2)*D*P*QR
DU( 4)= ALP(2)*P*QR*A5
DU( 5)=-ALP(1)*F3*X*S/R5 -ALP(2)*Y*P*QRX
DU( 6)= ALP(1)*F3*X*T/R5 -ALP(2)*D*P*QRX
DU( 7)= ALP(2)*F3*X/R5*VY
DU( 8)= ALP(1)*(S2D/R3-F3*Y*S/R5) +ALP(2)*(F3*Y/R5*VY+P*QR)
DU( 9)=-ALP(1)*(C2D/R3-F3*Y*T/R5) +ALP(2)*F3*D/R5*VY
DU(10)= ALP(2)*F3*X/R5*VZ
DU(11)= ALP(1)*(C2D/R3+F3*D*S/R5) +ALP(2)*F3*Y/R5*VZ
DU(12)= ALP(1)*(S2D/R3-F3*D*T/R5) +ALP(2)*(F3*D/R5*VZ-P*QR)
do 333 I=1,12
U(I)=U(I)+POT2/PI2*DU(I)
333 enddo
endif
!========================================
!===== TENSILE-FAULT CONTRIBUTION =====
!========================================
if(POT3/=F0) then
DU( 1)= ALP(1)*X/R3 -ALP(2)*X*Q*QR
DU( 2)= ALP(1)*T/R3 -ALP(2)*Y*Q*QR
DU( 3)= ALP(1)*S/R3 -ALP(2)*D*Q*QR
DU( 4)= ALP(1)*A3/R3 -ALP(2)*Q*QR*A5
DU( 5)=-ALP(1)*F3*X*T/R5 +ALP(2)*Y*Q*QRX
DU( 6)=-ALP(1)*F3*X*S/R5 +ALP(2)*D*Q*QRX
DU( 7)=-ALP(1)*F3*XY/R5 -ALP(2)*X*QR*WY
DU( 8)= ALP(1)*(C2D/R3-F3*Y*T/R5) -ALP(2)*(Y*WY+Q)*QR
DU( 9)= ALP(1)*(S2D/R3-F3*Y*S/R5) -ALP(2)*D*QR*WY
DU(10)= ALP(1)*F3*X*D/R5 -ALP(2)*X*QR*WZ
DU(11)=-ALP(1)*(S2D/R3-F3*D*T/R5) -ALP(2)*Y*QR*WZ
DU(12)= ALP(1)*(C2D/R3+F3*D*S/R5) -ALP(2)*(D*WZ-Q)*QR
do 444 I=1,12
U(I)=U(I)+POT3/PI2*DU(I)
444 enddo
endif
!=========================================
!===== INFLATE SOURCE CONTRIBUTION =====
!=========================================
if(POT4/=F0) then
DU( 1)=-ALP(1)*X/R3
DU( 2)=-ALP(1)*Y/R3
DU( 3)=-ALP(1)*D/R3
DU( 4)=-ALP(1)*A3/R3
DU( 5)= ALP(1)*F3*XY/R5
DU( 6)= ALP(1)*F3*X*D/R5
DU( 7)= DU(5)
DU( 8)=-ALP(1)*B3/R3
DU( 9)= ALP(1)*F3*Y*D/R5
DU(10)=-DU(6)
DU(11)=-DU(9)
DU(12)= ALP(1)*C3/R3
do 555 I=1,12
U(I)=U(I)+POT4/PI2*DU(I)
555 enddo
endif
return
end subroutine UA0
!----------------------------------------------------------------------
!----------------------------------------------------------------------
subroutine UB0(X,Y,D,Z,POT1,POT2,POT3,POT4,SD,CD,ALP,U)
!********************************************************************
!***** DISPLACEMENT AND STRAIN AT DEPTH (PART-B) *****
!***** DUE TO BURIED POINT SOURCE IN A SEMIINFINITE MEDIUM *****
!********************************************************************
!
!***** INPUT
!***** X,Y,D,Z : STATION COORDINATES IN FAULT SYSTEM
!***** POT1-POT4 : STRIKE-, DIP-, TENSILE- AND INFLATE-POTENCY
!***** OUTPUT
!***** U(12) : DISPLACEMENT AND THEIR DERIVATIVES
implicit none
! arguments
real*8, intent(in) :: X,Y,D,Z
real*8, intent(in) :: POT1,POT2,POT3,POT4
real*8, intent(in) :: SD,CD
real*8, intent(in) :: ALP(5)
real*8, intent(out) :: U(12)
! local variables
real*8 :: DU(12)
real*8 :: P,Q,S,T
real*8 :: R, R2, R3, R5
real*8 :: QR,QRX
real*8 :: XY,X2,Y2,D2,A3,A5,B3,C3
real*8 :: UY,VY,WY,UZ,VZ,WZ
real*8 :: C,RD
real*8 :: D12,D32,D33,D53,D54
real*8 :: FI1,FI2,FI3,FI4,FI5
real*8 :: FJ1,FJ2,FJ3,FJ4
real*8 :: FK1,FK2,FK3
! parameters
real*8, parameter :: PI2=6.283185307179586D0
real*8, parameter :: F0=0.0d0, F1=1.0d0, F2=2.0d0, F3=3.0d0, F4=4.0d0, F5=5.0d0, F8=8.0d0, F9=9.0d0
! loop counter
integer :: I
DU(1:12)=0.0d0
U(1:12)=0.0d0
call DCCON1(X,Y,D,SD,CD,R,P,Q,S,T)
XY=X*Y
X2=X*X
Y2=Y*Y
D2=D*D
R2=R**2.0d0
R3=R**3.0d0
R5=R**5.0d0
QR=F3*Q/R5 ! 3q/(R^5)
QRX=F5*QR*X/R2 ! 15qx/(R^7)
! -- Eq.(8), p.1024 --
A3=F1-F3*X2/R2
A5=F1-F5*X2/R2
B3=F1-F3*Y2/R2
C3=F1-F3*D2/R2
!-----
! -- Tab.4 and 5, pp.1027-1028 --
UY=SD-F5*Y*Q/R2 ! U in Tab.4
UZ=CD+F5*D*Q/R2 ! U' in Tab.5
VY=S -F5*Y*P*Q/R2 ! V in Tab.4
VZ=T +F5*D*P*Q/R2 ! V' in Tab.5
WY=UY+SD ! W in Tab. 4
WZ=UZ+CD ! W' in Tab.5
!-----
C=D+Z
RD=R+D
D12=F1/(R*RD*RD)
D32=D12*(F2*R+D)/R2
D33=D12*(F3*R+D)/(R2*RD)
D53=D12*(F8*R2+F9*R*D+F3*D2)/(R2*R2*RD)
D54=D12*(F5*R2+F4*R*D+D2)/R3*D12
!-----
FI1= Y*(D12-X2*D33)
FI2= X*(D12-Y2*D33)
FI3= X/R3-FI2
FI4=-XY*D32
FI5= F1/(R*RD)-X2*D32
FJ1=-F3*XY*(D33-X2*D54)
FJ2= F1/R3-F3*D12+F3*X2*Y2*D54
FJ3= A3/R3-FJ2
FJ4=-F3*XY/R5-FJ1
FK1=-Y*(D32-X2*D53)
FK2=-X*(D32-Y2*D53)
FK3=-F3*X*D/R5-FK2
!-----
!======================================
!===== STRIKE-SLIP CONTRIBUTION =====
!======================================
if(POT1/=F0) then
DU( 1)=-X2*QR -ALP(3)*FI1*SD
DU( 2)=-XY*QR -ALP(3)*FI2*SD
DU( 3)=-C*X*QR -ALP(3)*FI4*SD
DU( 4)=-X*QR*(F1+A5) -ALP(3)*FJ1*SD
DU( 5)=-Y*QR*A5 -ALP(3)*FJ2*SD
DU( 6)=-C*QR*A5 -ALP(3)*FK1*SD
DU( 7)=-F3*X2/R5*UY -ALP(3)*FJ2*SD
DU( 8)=-F3*XY/R5*UY-X*QR -ALP(3)*FJ4*SD
DU( 9)=-F3*C*X/R5*UY -ALP(3)*FK2*SD
DU(10)=-F3*X2/R5*UZ +ALP(3)*FK1*SD
DU(11)=-F3*XY/R5*UZ +ALP(3)*FK2*SD
DU(12)= F3*X/R5*(-C*UZ +ALP(3)*Y*SD)
do 222 I=1,12
U(I)=U(I)+POT1/PI2*DU(I)
222 enddo
endif
!===================================
!===== DIP-SLIP CONTRIBUTION =====
!===================================
if(POT2/=F0) then
DU( 1)=-X*P*QR +ALP(3)*FI3*SD*CD
DU( 2)=-Y*P*QR +ALP(3)*FI1*SD*CD
DU( 3)=-C*P*QR +ALP(3)*FI5*SD*CD
DU( 4)=-P*QR*A5 +ALP(3)*FJ3*SD*CD
DU( 5)= Y*P*QRX +ALP(3)*FJ1*SD*CD
DU( 6)= C*P*QRX +ALP(3)*FK3*SD*CD
DU( 7)=-F3*X/R5*VY +ALP(3)*FJ1*SD*CD
DU( 8)=-F3*Y/R5*VY-P*QR +ALP(3)*FJ2*SD*CD
DU( 9)=-F3*C/R5*VY +ALP(3)*FK1*SD*CD
DU(10)=-F3*X/R5*VZ -ALP(3)*FK3*SD*CD
DU(11)=-F3*Y/R5*VZ -ALP(3)*FK1*SD*CD
DU(12)=-F3*C/R5*VZ +ALP(3)*A3/R3*SD*CD
do 333 I=1,12
U(I)=U(I)+POT2/PI2*DU(I)
333 enddo
endif
!========================================
!===== TENSILE-FAULT CONTRIBUTION =====
!========================================
if(POT3/=F0) then
DU( 1)= X*Q*QR -ALP(3)*FI3*SD*SD
DU( 2)= Y*Q*QR -ALP(3)*FI1*SD*SD
DU( 3)= C*Q*QR -ALP(3)*FI5*SD*SD
DU( 4)= Q*QR*A5 -ALP(3)*FJ3*SD*SD
DU( 5)=-Y*Q*QRX -ALP(3)*FJ1*SD*SD
DU( 6)=-C*Q*QRX -ALP(3)*FK3*SD*SD
DU( 7)= X*QR*WY -ALP(3)*FJ1*SD*SD
DU( 8)= QR*(Y*WY+Q) -ALP(3)*FJ2*SD*SD
DU( 9)= C*QR*WY -ALP(3)*FK1*SD*SD
DU(10)= X*QR*WZ +ALP(3)*FK3*SD*SD
DU(11)= Y*QR*WZ +ALP(3)*FK1*SD*SD
DU(12)= C*QR*WZ -ALP(3)*A3/R3*SD*SD
do 444 I=1,12
U(I)=U(I)+POT3/PI2*DU(I)
444 enddo
endif
!=========================================
!===== INFLATE SOURCE CONTRIBUTION =====
!=========================================
if(POT4/=F0) then
DU( 1)= ALP(3)*X/R3
DU( 2)= ALP(3)*Y/R3
DU( 3)= ALP(3)*D/R3
DU( 4)= ALP(3)*A3/R3
DU( 5)=-ALP(3)*F3*XY/R5
DU( 6)=-ALP(3)*F3*X*D/R5
DU( 7)= DU(5)
DU( 8)= ALP(3)*B3/R3
DU( 9)=-ALP(3)*F3*Y*D/R5
DU(10)=-DU(6)
DU(11)=-DU(9)
DU(12)=-ALP(3)*C3/R3
do 555 I=1,12
U(I)=U(I)+POT4/PI2*DU(I)
555 enddo
endif
return
end subroutine UB0
!----------------------------------------------------------------------
!----------------------------------------------------------------------
subroutine UC0(X,Y,D,Z,POT1,POT2,POT3,POT4,SD,CD,ALP,U)
!********************************************************************
!***** DISPLACEMENT AND STRAIN AT DEPTH (PART-B) *****
!***** DUE TO BURIED POINT SOURCE IN A SEMIINFINITE MEDIUM *****
!********************************************************************
!
!***** INPUT
!***** X,Y,D,Z : STATION COORDINATES IN FAULT SYSTEM
!***** POT1-POT4 : STRIKE-, DIP-, TENSILE- AND INFLATE-POTENCY
!***** OUTPUT
!***** U(12) : DISPLACEMENT AND THEIR DERIVATIVES
implicit none
! arguments
real*8, intent(in) :: X,Y,D,Z
real*8, intent(in) :: POT1,POT2,POT3,POT4
real*8, intent(in) :: SD,CD
real*8, intent(in) :: ALP(5)
real*8, intent(out) :: U(12)
! local variables
real*8 :: DU(12)
real*8 :: P,Q,S,T
real*8 :: R, R2, R3, R5, R7
real*8 :: S2D,C2D
real*8 :: Q2,QR,QRX,QR5,QR7,DR5
real*8 :: XY,X2,Y2,D2,C
real*8 :: A3,A5,A7,B3,B5,B7,C3,C5,C7,D7
! parameters
real*8, parameter :: PI2=6.283185307179586D0
real*8, parameter :: F0=0.0d0, F1=1.0d0, F2=2.0d0, F3=3.0d0, F5=5.0d0, F7=7.0d0, F10=1.0d1, F15=1.5d1
! loop counter
integer :: I
U(1:12)=0.0d0
DU(1:12)=0.0d0
call DCCON1(X,Y,D,SD,CD,R,P,Q,S,T)
XY=X*Y
X2=X*X
Y2=Y*Y
D2=D*D
R2=R**2.0d0
R3=R**3.0d0
R5=R**5.0d0
QR=F3*Q/R5 ! 3q/(R^5)
QRX=F5*QR*X/R2 ! 15qx/(R^7)
! -- Eq.(8), p.1024 --
A3=F1-F3*X2/R2
A5=F1-F5*X2/R2
B3=F1-F3*Y2/R2
C3=F1-F3*D2/R2
!-----
S2D=2.0d0*SD*CD
C2D=CD*CD-SD*SD
!-----
C=D+Z
Q2=Q*Q
R7=R5*R2
A7=F1-F7*X2/R2
B5=F1-F5*Y2/R2
B7=F1-F7*Y2/R2
C5=F1-F5*D2/R2
C7=F1-F7*D2/R2
D7=F2-F7*Q2/R2
QR5=F5*Q/R2
QR7=F7*Q/R2
DR5=F5*D/R2
!-----
!======================================
!===== STRIKE-SLIP CONTRIBUTION =====
!======================================
if(POT1/=F0) then
DU( 1)=-ALP(4)*A3/R3*CD +ALP(5)*C*QR*A5
DU( 2)= F3*X/R5*( ALP(4)*Y*CD +ALP(5)*C*(SD-Y*QR5) )
DU( 3)= F3*X/R5*(-ALP(4)*Y*SD +ALP(5)*C*(CD+D*QR5) )
DU( 4)= ALP(4)*F3*X/R5*(F2+A5)*CD -ALP(5)*C*QRX*(F2+A7)
DU( 5)= F3/R5*( ALP(4)*Y*A5*CD +ALP(5)*C*(A5*SD-Y*QR5*A7) )
DU( 6)= F3/R5*(-ALP(4)*Y*A5*SD +ALP(5)*C*(A5*CD+D*QR5*A7) )
DU( 7)= DU(5)
DU( 8)= F3*X/R5*( ALP(4)*B5*CD -ALP(5)*F5*C/R2*(F2*Y*SD+Q*B7) )
DU( 9)= F3*X/R5*(-ALP(4)*B5*SD +ALP(5)*F5*C/R2*(D*B7*SD-Y*C7*CD) )
DU(10)= F3/R5* (-ALP(4)*D*A5*CD +ALP(5)*C*(A5*CD+D*QR5*A7) )
DU(11)= F15*X/R7*( ALP(4)*Y*D*CD +ALP(5)*C*(D*B7*SD-Y*C7*CD) )
DU(12)= F15*X/R7*(-ALP(4)*Y*D*SD +ALP(5)*C*(F2*D*CD-Q*C7) )
do 222 I=1,12
U(I)=U(I)+POT1/PI2*DU(I)
222 enddo
endif
!===================================
!===== DIP-SLIP CONTRIBUTION =====
!===================================
if(POT2/=F0) then
DU( 1)= ALP(4)*F3*X*T/R5 -ALP(5)*C*P*QRX
DU( 2)=-ALP(4)/R3*(C2D-F3*Y*T/R2) +ALP(5)*F3*C/R5*(S-Y*P*QR5)
DU( 3)=-ALP(4)*A3/R3*SD*CD +ALP(5)*F3*C/R5*(T+D*P*QR5)
DU( 4)= ALP(4)*F3*T/R5*A5 -ALP(5)*F5*C*P*QR/R2*A7
DU( 5)= F3*X/R5*(ALP(4)*(C2D-F5*Y*T/R2)-ALP(5)*F5*C/R2*(S-Y*P*QR7))
DU( 6)= F3*X/R5*(ALP(4)*(F2+A5)*SD*CD -ALP(5)*F5*C/R2*(T+D*P*QR7))
DU( 7)= DU(5)
DU( 8)= F3/R5*( ALP(4)*(F2*Y*C2D+T*B5) &
+ALP(5)*C*(S2D-F10*Y*S/R2-P*QR5*B7))
DU( 9)= F3/R5*(ALP(4)*Y*A5*SD*CD-ALP(5)*C*((F3+A5)*C2D+Y*P*DR5*QR7))
DU(10)= F3*X/R5*(-ALP(4)*(S2D-T*DR5) -ALP(5)*F5*C/R2*(T+D*P*QR7))
DU(11)= F3/R5*(-ALP(4)*(D*B5*C2D+Y*C5*S2D) &
-ALP(5)*C*((F3+A5)*C2D+Y*P*DR5*QR7))
DU(12)= F3/R5*(-ALP(4)*D*A5*SD*CD-ALP(5)*C*(S2D-F10*D*T/R2+P*QR5*C7))
do 333 I=1,12
U(I)=U(I)+POT2/PI2*DU(I)
333 enddo
endif
!========================================
!===== TENSILE-FAULT CONTRIBUTION =====
!========================================
if(POT3/=F0) then
DU( 1)= F3*X/R5*(-ALP(4)*S +ALP(5)*(C*Q*QR5-Z))
DU( 2)= ALP(4)/R3*(S2D-F3*Y*S/R2)+ALP(5)*F3/R5*(C*(T-Y+Y*Q*QR5)-Y*Z)
DU( 3)=-ALP(4)/R3*(F1-A3*SD*SD) -ALP(5)*F3/R5*(C*(S-D+D*Q*QR5)-D*Z)
DU( 4)=-ALP(4)*F3*S/R5*A5 +ALP(5)*(C*QR*QR5*A7-F3*Z/R5*A5)
DU( 5)= F3*X/R5*(-ALP(4)*(S2D-F5*Y*S/R2) &
-ALP(5)*F5/R2*(C*(T-Y+Y*Q*QR7)-Y*Z))
DU( 6)= F3*X/R5*( ALP(4)*(F1-(F2+A5)*SD*SD) &
+ALP(5)*F5/R2*(C*(S-D+D*Q*QR7)-D*Z))
DU( 7)= DU(5)
DU( 8)= F3/R5*(-ALP(4)*(F2*Y*S2D+S*B5) &
-ALP(5)*(C*(F2*SD*SD+F10*Y*(T-Y)/R2-Q*QR5*B7)+Z*B5))
DU( 9)= F3/R5*( ALP(4)*Y*(F1-A5*SD*SD) &
+ALP(5)*(C*(F3+A5)*S2D-Y*DR5*(C*D7+Z)))
DU(10)= F3*X/R5*(-ALP(4)*(C2D+S*DR5) &
+ALP(5)*(F5*C/R2*(S-D+D*Q*QR7)-F1-Z*DR5))
DU(11)= F3/R5*( ALP(4)*(D*B5*S2D-Y*C5*C2D) &
+ALP(5)*(C*((F3+A5)*S2D-Y*DR5*D7)-Y*(F1+Z*DR5)))
DU(12)= F3/R5*(-ALP(4)*D*(F1-A5*SD*SD) &
-ALP(5)*(C*(C2D+F10*D*(S-D)/R2-Q*QR5*C7)+Z*(F1+C5)))
do 444 I=1,12
U(I)=U(I)+POT3/PI2*DU(I)
444 enddo
endif
!=========================================
!===== INFLATE SOURCE CONTRIBUTION =====
!=========================================
if(POT4/=F0) then
DU( 1)= ALP(4)*F3*X*D/R5
DU( 2)= ALP(4)*F3*Y*D/R5
DU( 3)= ALP(4)*C3/R3
DU( 4)= ALP(4)*F3*D/R5*A5
DU( 5)=-ALP(4)*F15*XY*D/R7
DU( 6)=-ALP(4)*F3*X/R5*C5
DU( 7)= DU(5)
DU( 8)= ALP(4)*F3*D/R5*B5
DU( 9)=-ALP(4)*F3*Y/R5*C5
DU(10)= DU(6)
DU(11)= DU(9)
DU(12)= ALP(4)*F3*D/R5*(F2+C5)
do 555 I=1,12
U(I)=U(I)+POT4/PI2*DU(I)
555 enddo
endif
return
end subroutine UC0
!----------------------------------------------------------------------
!----------------------------------------------------------------------
subroutine DC3D(ALPHA,X,Y,Z,DEPTH,DIP, &
AL1,AL2,AW1,AW2,DISL1,DISL2,DISL3, &
UX,UY,UZ,UXX,UYX,UZX,UXY,UYY,UZY,UXZ,UYZ,UZZ,IRET)
!********************************************************************
!***** *****
!***** DISPLACEMENT AND STRAIN AT DEPTH *****
!***** DUE TO BURIED FINITE FAULT IN A SEMIINFINITE MEDIUM *****
!***** CODED BY Y.OKADA ... SEP.1991 *****
!***** REVISED ... NOV.1991, APR.1992, MAY.1993, *****
!***** JUL.1993, MAY.2002 *****
!--------------------------------------------------------------------
!----- converted to Fortran90 (free form) -----
!----- T. Miyashita, Jan. 2020 -----
!--------------------------------------------------------------------
!********************************************************************
!
!***** INPUT
!***** ALPHA : MEDIUM CONSTANT (LAMBDA+MYU)/(LAMBDA+2*MYU)
!***** X,Y,Z : COORDINATE OF OBSERVING POINT
!***** DEPTH : DEPTH OF REFERENCE POINT
!***** DIP : DIP-ANGLE (DEGREE)
!***** AL1,AL2 : FAULT LENGTH RANGE
!***** AW1,AW2 : FAULT WIDTH RANGE
!***** DISL1-DISL3 : STRIKE-, DIP-, TENSILE-DISLOCATIONS
!
!***** OUTPUT
!***** UX, UY, UZ : DISPLACEMENT ( UNIT=(UNIT OF DISL)
!***** UXX,UYX,UZX : X-DERIVATIVE ( UNIT=(UNIT OF DISL) /
!***** UXY,UYY,UZY : Y-DERIVATIVE (UNIT OF X,Y,Z,DEPTH,AL,AW) )
!***** UXZ,UYZ,UZZ : Z-DERIVATIVE
!***** IRET : return CODE
!***** : =0....NORMAL
!***** : =1....SINGULAR
!***** : =2....POSITIVE Z WAS GIVEN
implicit none
! arguments
real*8, intent(in) :: ALPHA,X,Y,Z,DEPTH,DIP,AL1,AL2,AW1,AW2,DISL1,DISL2,DISL3
real*8, intent(out) :: UX,UY,UZ,UXX,UYX,UZX,UXY,UYY,UZY,UXZ,UYZ,UZZ
integer, intent(out) :: IRET
! local variables
real*8 :: SD,CD
real*8 :: XI(2),ET(2)
integer :: KXI(2),KET(2)
real*8 :: U(12),DU(12),DUA(12),DUB(12),DUC(12)
real*8 :: DD1, DD2, DD3
real*8 :: ZZ, D, P, Q, R12, R21, R22
real*8 :: ALP(5)
! parameters
real*8, parameter :: F0 = 0.0d0
real*8, parameter :: EPS = 1.0d-6
! loop counters
integer :: I,J,K
! initialization
U(1:12) = 0.0d0
DU(1:12) = 0.0d0
DUA(1:12) = 0.0d0
DUB(1:12) = 0.0d0
DUC(1:12) = 0.0d0
call varout(U,UX,UY,UZ,UXX,UYX,UZX,UXY,UYY,UZY,UXZ,UYZ,UZZ)
!-----
IRET=0
if(Z>0.0d0) then
IRET=2
return
endif
!-----
ZZ=Z
DD1=DISL1
DD2=DISL2
DD3=DISL3
!### CAUTION ### if XI,ET,Q ARE SUFFICIENTLY SMALL, THEY ARE SET TO ZER0
XI(1)=X-AL1
XI(2)=X-AL2
if(dabs(XI(1))<EPS) XI(1)=F0
if(dabs(XI(2))<EPS) XI(2)=F0
!======================================
!===== REAL-SOURCE CONTRIBUTION =====
!======================================
call assign_alpha(ALPHA,ALP)
call DCCON0(DIP,SD,CD)
!-----
D=DEPTH+Z
P=Y*CD+D*SD
Q=Y*SD-D*CD
ET(1)=P-AW1
ET(2)=P-AW2
if(dabs(Q)<EPS) Q=F0
if(dabs(ET(1))<EPS) ET(1)=F0
if(dabs(ET(2))<EPS) ET(2)=F0
!--------------------------------
!----- REJECT SINGULAR CASE -----
!--------------------------------
!----- ON FAULT EDGE
if(Q==F0 .and. &
( (XI(1)*XI(2)<=F0 .and. ET(1)*ET(2)==F0) &
.or.(ET(1)*ET(2)<=F0 .and. XI(1)*XI(2)==F0) )) then
IRET=1
return
endif
!----- ON NEGATIVE EXTENSION OF FAULT EDGE
KXI(1)=0
KXI(2)=0
KET(1)=0
KET(2)=0
R12=dsqrt(XI(1)*XI(1)+ET(2)*ET(2)+Q*Q)
R21=dsqrt(XI(2)*XI(2)+ET(1)*ET(1)+Q*Q)
R22=dsqrt(XI(2)*XI(2)+ET(2)*ET(2)+Q*Q)
if(XI(1)<F0 .and. R21+XI(2)<EPS) KXI(1)=1
if(XI(1)<F0 .and. R22+XI(2)<EPS) KXI(2)=1
if(ET(1)<F0 .and. R12+ET(2)<EPS) KET(1)=1
if(ET(1)<F0 .and. R22+ET(2)<EPS) KET(2)=1
!=====
do 223 K=1,2
do 222 J=1,2
call UA(XI(J),ET(K),Q,DD1,DD2,DD3,KXI(K),KET(J),SD,CD,ALP,DUA)
!-----
do 220 I=1,10,3
DU(I) =-DUA(I)
DU(I+1)=-DUA(I+1)*CD+DUA(I+2)*SD
DU(I+2)=-DUA(I+1)*SD-DUA(I+2)*CD
if(I<10) cycle
DU(I) =-DU(I)
DU(I+1)=-DU(I+1)
DU(I+2)=-DU(I+2)
220 enddo
do 221 I=1,12
if(J+K/=3) U(I)=U(I)+DU(I)
if(J+K==3) U(I)=U(I)-DU(I)
221 enddo
!-----
222 enddo
223 enddo
!=======================================
!===== IMAGE-SOURCE CONTRIBUTION =====
!=======================================
D=DEPTH-Z
P=Y*CD+D*SD
Q=Y*SD-D*CD
ET(1)=P-AW1
ET(2)=P-AW2
if(dabs(Q)<EPS) Q=F0
if(dabs(ET(1))<EPS) ET(1)=F0
if(dabs(ET(2))<EPS) ET(2)=F0
!--------------------------------
!----- REJECT SINGULAR CASE -----
!--------------------------------
!----- ON FAULT EDGE
if(Q==F0 .and. &
( (XI(1)*XI(2)<=F0 .and. ET(1)*ET(2)==F0) &
.or.(ET(1)*ET(2)<=F0 .and. XI(1)*XI(2)==F0) )) then
IRET=1
call varout(U,UX,UY,UZ,UXX,UYX,UZX,UXY,UYY,UZY,UXZ,UYZ,UZZ)
return
endif
!----- ON NEGATIVE EXTENSION OF FAULT EDGE
KXI(1)=0
KXI(2)=0
KET(1)=0
KET(2)=0
R12=dsqrt(XI(1)*XI(1)+ET(2)*ET(2)+Q*Q)
R21=dsqrt(XI(2)*XI(2)+ET(1)*ET(1)+Q*Q)
R22=dsqrt(XI(2)*XI(2)+ET(2)*ET(2)+Q*Q)
if(XI(1)<F0 .and. R21+XI(2)<EPS) KXI(1)=1
if(XI(1)<F0 .and. R22+XI(2)<EPS) KXI(2)=1
if(ET(1)<F0 .and. R12+ET(2)<EPS) KET(1)=1
if(ET(1)<F0 .and. R22+ET(2)<EPS) KET(2)=1
!=====
do 334 K=1,2
do 333 J=1,2
call UA(XI(J),ET(K),Q ,DD1,DD2,DD3,KXI(K),KET(J),SD,CD,ALP,DUA)
call UB(XI(J),ET(K),Q ,DD1,DD2,DD3,KXI(K),KET(J),SD,CD,ALP,DUB)
call UC(XI(J),ET(K),Q,ZZ,DD1,DD2,DD3,KXI(K),KET(J),SD,CD,ALP,DUC)
!-----
do 330 I=1,10,3
DU(I)=DUA(I)+DUB(I)+Z*DUC(I)
DU(I+1)=(DUA(I+1)+DUB(I+1)+Z*DUC(I+1))*CD &
-(DUA(I+2)+DUB(I+2)+Z*DUC(I+2))*SD
DU(I+2)=(DUA(I+1)+DUB(I+1)-Z*DUC(I+1))*SD &
+(DUA(I+2)+DUB(I+2)-Z*DUC(I+2))*CD
if(I<10) cycle
DU(10)=DU(10)+DUC(1)
DU(11)=DU(11)+DUC(2)*CD-DUC(3)*SD
DU(12)=DU(12)-DUC(2)*SD-DUC(3)*CD
330 enddo
do 331 I=1,12
if(J+K/=3) U(I)=U(I)+DU(I)
if(J+K==3) U(I)=U(I)-DU(I)
331 enddo
!-----
333 enddo
334 enddo
!=====
call varout(U,UX,UY,UZ,UXX,UYX,UZX,UXY,UYY,UZY,UXZ,UYZ,UZZ)
return
end subroutine DC3D
!----------------------------------------------------------------------
!----------------------------------------------------------------------
subroutine UA(XI,ET,Q,DISL1,DISL2,DISL3,KXI,KET,SD,CD,ALP,U)
!
!********************************************************************
!***** DISPLACEMENT AND STRAIN AT DEPTH (PART-A) *****
!***** DUE TO BURIED FINITE FAULT IN A SEMIINFINITE MEDIUM *****
!********************************************************************
!
!***** INPUT
!***** XI,ET,Q : STATION COORDINATES IN FAULT SYSTEM
!***** DISL1-DISL3 : STRIKE-, DIP-, TENSILE-DISLOCATIONS
!***** KXI,KET : KXI=1, KET=1 MEANS R+XI<EPS, R+ET<EPS, RESPECTIVELY
!***** SD,CD : SIN, COS OF DIP-ANGLE
!***** ALP : COEFFICIENTS RELATED TO ALPHA VALUE
!***** OUTPUT
!***** U(12) : DISPLACEMENT AND THEIR DERIVATIVES
!-----
implicit none
! arguments
real*8, intent(in) :: XI,ET,Q,DISL1,DISL2,DISL3
integer, intent(in) :: KXI,KET
real*8, intent(in) :: SD,CD
real*8, intent(in) :: ALP(5)
real*8, intent(out) :: U(12)
! local variables
real*8 :: DU(12)
real*8 :: R,Ytilde,Dtilde
real*8 :: THETA,ALX,ALE
real*8 :: X11,X32,Y11,Y32
real*8 :: EY,EZ,FY,FZ,GY,GZ,HY,HZ
real*8 :: XY,QX,QY
real*8 :: XI2,Q2
real*8 :: R3
! parameters
real*8, parameter :: F0=0.0d0, F2=2.0d0
real*8, parameter :: PI2=6.283185307179586d0
! loop counter
integer :: I
U(1:12) = 0.0d0
DU(1:12) = 0.0d0
call DCCON2(XI,ET,Q,SD,CD,R,Ytilde,Dtilde)
call math_singularity(XI,ET,Q,R,KXI,KET,THETA,ALX,ALE)
call eq14_xy(XI,ET,KXI,KET,R,X11,X32,Y11,Y32)
call auxvar_derivative_yz(XI,Q,SD,CD,R,Ytilde,Dtilde,X11,X32,Y32, &
EY,EZ,FY,FZ,GY,GZ,HY,HZ)
R3=R**3.0d0
XI2=XI*XI
Q2=Q*Q
XY=XI*Y11
QX=Q *X11
QY=Q *Y11
!======================================
!===== STRIKE-SLIP CONTRIBUTION =====
!======================================
if(DISL1/=F0) then
DU( 1)= THETA/F2 +ALP(2)*XI*QY
DU( 2)= ALP(2)*Q/R
DU( 3)= ALP(1)*ALE -ALP(2)*Q*QY
DU( 4)=-ALP(1)*QY -ALP(2)*XI2*Q*Y32
DU( 5)= -ALP(2)*XI*Q/R3
DU( 6)= ALP(1)*XY +ALP(2)*XI*Q2*Y32
DU( 7)= ALP(1)*XY*SD +ALP(2)*XI*FY+Dtilde/F2*X11
DU( 8)= ALP(2)*EY
DU( 9)= ALP(1)*(CD/R+QY*SD) -ALP(2)*Q*FY
DU(10)= ALP(1)*XY*CD +ALP(2)*XI*FZ+Ytilde/F2*X11
DU(11)= ALP(2)*EZ
DU(12)=-ALP(1)*(SD/R-QY*CD) -ALP(2)*Q*FZ
do 222 I=1,12
U(I)=U(I)+DISL1/PI2*DU(I)
222 enddo
endif
!======================================
!===== DIP-SLIP CONTRIBUTION =====
!======================================
if(DISL2/=F0) then
DU( 1)= ALP(2)*Q/R
DU( 2)= THETA/F2 +ALP(2)*ET*QX
DU( 3)= ALP(1)*ALX -ALP(2)*Q*QX
DU( 4)= -ALP(2)*XI*Q/R3
DU( 5)= -QY/F2 -ALP(2)*ET*Q/R3
DU( 6)= ALP(1)/R +ALP(2)*Q2/R3
DU( 7)= ALP(2)*EY
DU( 8)= ALP(1)*Dtilde*X11+XY/F2*SD +ALP(2)*ET*GY
DU( 9)= ALP(1)*Ytilde*X11 -ALP(2)*Q*GY
DU(10)= ALP(2)*EZ
DU(11)= ALP(1)*Ytilde*X11+XY/F2*CD +ALP(2)*ET*GZ
DU(12)=-ALP(1)*Dtilde*X11 -ALP(2)*Q*GZ
do 333 I=1,12
U(I)=U(I)+DISL2/PI2*DU(I)
333 enddo
endif
!========================================
!===== TENSILE-FAULT CONTRIBUTION =====
!========================================
if(DISL3/=F0) then
DU( 1)=-ALP(1)*ALE -ALP(2)*Q*QY
DU( 2)=-ALP(1)*ALX -ALP(2)*Q*QX
DU( 3)= THETA/F2 -ALP(2)*(ET*QX+XI*QY)
DU( 4)=-ALP(1)*XY +ALP(2)*XI*Q2*Y32
DU( 5)=-ALP(1)/R +ALP(2)*Q2/R3
DU( 6)=-ALP(1)*QY -ALP(2)*Q*Q2*Y32
DU( 7)=-ALP(1)*(CD/R+QY*SD) -ALP(2)*Q*FY
DU( 8)=-ALP(1)*Ytilde*X11 -ALP(2)*Q*GY
DU( 9)= ALP(1)*(Dtilde*X11+XY*SD) +ALP(2)*Q*HY
DU(10)= ALP(1)*(SD/R-QY*CD) -ALP(2)*Q*FZ
DU(11)= ALP(1)*Dtilde*X11 -ALP(2)*Q*GZ
DU(12)= ALP(1)*(Ytilde*X11+XY*CD) +ALP(2)*Q*HZ
do 444 I=1,12
U(I)=U(I)+DISL3/PI2*DU(I)
444 enddo
endif
return
end subroutine UA
!----------------------------------------------------------------------
!----------------------------------------------------------------------
subroutine UB(XI,ET,Q,DISL1,DISL2,DISL3,KXI,KET,SD,CD,ALP,U)
!********************************************************************
!***** DISPLACEMENT AND STRAIN AT DEPTH (PART-B) *****
!***** DUE TO BURIED FINITE FAULT IN A SEMIINFINITE MEDIUM *****
!********************************************************************
!
!***** INPUT
!***** XI,ET,Q : STATION COORDINATES IN FAULT SYSTEM
!***** DISL1-DISL3 : STRIKE-, DIP-, TENSILE-DISLOCATIONS
!***** KXI,KET : KXI=1, KET=1 MEANS R+XI<EPS, R+ET<EPS, RESPECTIVELY
!***** SD,CD : SIN, COS OF DIP-ANGLE
!***** ALP : COEFFICIENTS RELATED TO ALPHA VALUE
!***** OUTPUT
!***** U(12) : DISPLACEMENT AND THEIR DERIVATIVES
!-----
implicit none
! arguments
real*8, intent(in) :: XI,ET,Q,DISL1,DISL2,DISL3
integer, intent(in) :: KXI,KET
real*8, intent(in) :: SD,CD
real*8, intent(in) :: ALP(5)
real*8, intent(out) :: U(12)
! local variables
real*8 :: DU(12)
real*8 :: R,Ytilde,Dtilde
real*8 :: THETA,ALE
real*8 :: X11,X32,Y11,Y32
real*8 :: EY,EZ,FY,FZ,GY,GZ,HY,HZ
real*8 :: X
real*8 :: XY,QX,QY
real*8 :: XI2,Q2
real*8 :: R3
real*8 :: RD,RD2
real*8 :: D11
real*8 :: AI1,AI2,AI3,AI4
real*8 :: AJ1,AJ2,AJ3,AJ4,AJ5,AJ6
real*8 :: AK1,AK2,AK3,AK4
! parameters
real*8, parameter :: F0=0.0d0, F1=1.0d0, F2=2.0d0
real*8, parameter :: PI2=6.283185307179586d0
! loop counter
integer :: I
! unused (dummy) vars
real*8 :: dum ! ALX
U(1:12)=0.0d0
DU(1:12)=0.0d0
call DCCON2(XI,ET,Q,SD,CD,R,Ytilde,Dtilde)
call math_singularity(XI,ET,Q,R,KXI,KET,THETA,dum,ALE)
call eq14_xy(XI,ET,KXI,KET,R,X11,X32,Y11,Y32)
call auxvar_derivative_yz(XI,Q,SD,CD,R,Ytilde,Dtilde,X11,X32,Y32, &
EY,EZ,FY,FZ,GY,GZ,HY,HZ)
R3=R**3.0d0
XI2=XI*XI
Q2=Q*Q
RD=R+Dtilde
D11=F1/(R*RD)
AJ2=XI*Ytilde/RD*D11
AJ5=-(Dtilde+Ytilde*Ytilde/RD)*D11
if(CD/=F0) then
! p.1034 (ii)
if(XI==F0) then
AI4=F0
else
X=dsqrt(XI2+Q2)
AI4=F1/(CD*CD)*( XI/RD*SD*CD &
+F2*datan((ET*(X+Q*CD)+X*(R+X)*SD)/(XI*(R+X)*CD)) )
endif
AI3=(Ytilde*CD/RD-ALE+SD*dlog(RD))/(CD*CD)