build.gradle

buildscript {
    repositories {
        gradlePluginPortal()
        maven {
            name = "Forge"
            url = "https://maven.minecraftforge.net"
        }
    }
    dependencies {
        classpath 'com.modrinth.minotaur:Minotaur:2.+'
        classpath 'gradle.plugin.org.jetbrains.gradle.plugin.idea-ext:gradle-idea-ext:1.1.7' // Required for NeoGradle
    }
}

apply plugin: 'org.jetbrains.gradle.plugin.idea-ext'

allprojects { }

subprojects {
    apply plugin: 'java'
    apply plugin: 'idea'
    apply plugin: 'maven-publish'

    if (!project.name.equals("Common")) {
        apply plugin: 'com.modrinth.minotaur'
    }

    java.toolchain.languageVersion = JavaLanguageVersion.of(21)
    java.withSourcesJar()
    java.withJavadocJar()

    jar {
        manifest {
            attributes([
                    'Specification-Title'     : mod_name,
                    'Specification-Vendor'    : mod_authors,
                    'Specification-Version'   : mod_version,
                    'Implementation-Title'    : project.name,
                    'Implementation-Version'  : mod_version,
                    'Implementation-Vendor'   : mod_authors,
                    'Implementation-Timestamp': new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                    'Timestamp'               : System.currentTimeMillis(),
                    'Built-On-Java'           : "${System.getProperty('java.vm.version')} (${System.getProperty('java.vm.vendor')})",
                    'Build-On-Minecraft'      : minecraft_version
            ])
        }
    }

    sourcesJar {
        from(rootProject.file("LICENSE.md")) {
            rename { "${it}_${mod_name}" }
        }
    }

    repositories {
        mavenCentral()
        maven {
            name = 'Sponge / Mixin'
            url = 'https://repo.spongepowered.org/repository/maven-public/'
        }
        maven {
            name = 'Forge'
            url = "https://maven.minecraftforge.net"
        }
    }

    tasks.withType(JavaCompile).configureEach {
        it.options.encoding = 'UTF-8'
        it.options.release.set(21)
    }

    processResources {
        var expandProps = [
                minecraft_version             : minecraft_version,
                minecraft_version_range       : minecraft_version_range,
                forge_version                 : forge_version,
                forge_version_range           : forge_version_range,
                forge_loader_version_range    : forge_loader_version_range,
                neoforge_version              : neoforge_version,
                neoforge_version_range        : neoforge_version_range,
                neoforge_loader_version_range : neoforge_loader_version_range,
                fabric_version                : fabric_version,
                fabric_loader_version         : fabric_loader_version,
                mod_id                        : mod_id,
                mod_name                      : mod_name,
                mod_display_name              : mod_display_name,
                mod_version                   : mod_version,
                mod_authors                   : mod_authors,
                mod_description               : mod_description,
                mod_issues_url                : mod_issues_url,
                mod_page_url                  : mod_page_url,
                mod_git_url                   : mod_git_url,
                mod_license                   : mod_license
        ]

        filesMatching(['pack.mcmeta', 'fabric.mod.json', 'META-INF/mods.toml', 'META-INF/neoforge.mods.toml']) {
            expand expandProps
        }

        inputs.properties(expandProps)
    }

    // Disables Gradle's custom module metadata from being published to maven. The
    // metadata includes mapped dependencies which are not reasonably consumable by
    // other mod developers.
    tasks.withType(GenerateModuleMetadata) {
        enabled = false
    }
}