build.gradle

buildscript {
	ext {
		springBootVersion = '2.7.7'
	}
	repositories {
		mavenCentral()
	}
	dependencies {
		classpath "org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}"
		classpath "io.spring.gradle:dependency-management-plugin:1.1.0"
	}
}

subprojects {
	apply plugin: 'java'
	apply plugin: 'idea'
	apply plugin: 'org.springframework.boot'
	apply plugin: 'io.spring.dependency-management'
	apply plugin: 'jacoco'

	group 'io.eagle'
	version '0.0.1-SNAPSHOT'

	sourceCompatibility = '11'
//	targetCompatibility = '1.8'
//	compileJava.options.encoding = 'UTF-8'

	repositories {
		mavenCentral()
	}

	// 하위 모듈에서 공통으로 사용하는 세팅 추가
	dependencies {
		implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
		implementation 'org.springframework.boot:spring-boot-starter-data-redis'
		implementation 'org.redisson:redisson-spring-boot-starter:3.17.4'
		implementation 'org.springframework.boot:spring-boot-starter-security'
		implementation 'org.springframework.boot:spring-boot-starter-validation'
		implementation 'org.springframework.boot:spring-boot-starter-web'
		implementation 'org.springframework.boot:spring-boot-starter-oauth2-client'

		compileOnly 'org.projectlombok:lombok'
		developmentOnly 'org.springframework.boot:spring-boot-devtools'
		runtimeOnly 'com.mysql:mysql-connector-j'
		annotationProcessor 'org.projectlombok:lombok'
		testImplementation 'org.springframework.boot:spring-boot-starter-test'
		testImplementation 'org.springframework.security:spring-security-test'

		implementation group: 'io.jsonwebtoken', name: 'jjwt', version: '0.9.1'
		implementation group: 'javax.xml.bind', name: 'jaxb-api', version: '2.3.1'
		implementation "com.querydsl:querydsl-jpa"
		implementation "com.querydsl:querydsl-core"
		implementation "com.querydsl:querydsl-collections"
		implementation "org.qlrm:qlrm:3.0.4"
		annotationProcessor "com.querydsl:querydsl-apt:${dependencyManagement.importedProperties['querydsl.version']}:jpa" // querydsl JPAAnnotationProcessor 사용 지정
		annotationProcessor "jakarta.annotation:jakarta.annotation-api" // java.lang.NoClassDefFoundError (javax.annotation.Generated) 대응 코드
		annotationProcessor "jakarta.persistence:jakarta.persistence-api" // java.lang.NoClassDefFoundError (javax.annotation.Entity) 대응 코드

		testImplementation 'org.hamcrest:hamcrest:2.2'
		testImplementation 'org.junit.jupiter:junit-jupiter-api:5.6.0'
		testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine'
	}

	test {
		useJUnitPlatform()
	}

	configurations {
		compileOnly {
			extendsFrom annotationProcessor
		}
	}

	jacoco {
		toolVersion = '0.8.8'
	}

	tasks.named('test') {
		useJUnitPlatform()
		finalizedBy("jacocoTestReport")
	}

	tasks.jacocoTestReport {
		reports {
			html.enabled true
			xml.enabled true
		}

		finalizedBy("jacocoTestCoverageVerification")
	}

//	tasks.jacocoTestCoverageVerification {
//		violationRules {
//			rule {
//				enabled = true
//				element = "CLASS"
//
//				limit {
//					counter = 'LINE'
//					value = 'COVEREDRATIO'
//					minimum = 0.80
//				}
//
//				limit {
//					counter = "BRANCH"
//					value = "COVEREDRATIO"
//					minimum = 0.80
//				}
//			}
//		}
//	}

// Querydsl 설정부
	def generated = 'src/main/generated'

// querydsl QClass 파일 생성 위치를 지정
	tasks.withType(JavaCompile) {
		options.getGeneratedSourceOutputDirectory().set(file(generated))
	}

// java source set 에 querydsl QClass 위치 추가
	sourceSets {
		main.java.srcDirs += [ generated ]
	}

// gradle clean 시에 QClass 디렉토리 삭제
	clean {
		delete file(generated)
	}
}


project(':core'){
	bootJar { enabled = false }
	jar { enabled = true }


}

project(':api'){
	bootJar { enabled = true }
	jar { enabled = false }
	dependencies {
		implementation project(':core')
		implementation 'org.springframework.boot:spring-boot-starter-web'
		implementation "org.springframework.cloud:spring-cloud-starter-aws:2.2.6.RELEASE"
	}
}

project(':socket'){
	bootJar { enabled = true }
	jar { enabled = false }
	dependencies {
		implementation project(':core')
		implementation 'org.springframework.boot:spring-boot-starter-websocket'
		implementation 'org.springframework.kafka:spring-kafka'
		testImplementation 'org.springframework.kafka:spring-kafka-test'
		implementation "com.google.guava:guava:31.1-jre"
	}
}

project(':batch'){
	bootJar { enabled = true }
	jar { enabled = false }
	dependencies {
		implementation project(':core')
		implementation 'org.springframework.boot:spring-boot-starter-batch'
		implementation 'org.springframework.boot:spring-boot-starter-quartz'
		testImplementation 'org.springframework.batch:spring-batch-test'
	}
}